Method expected zero arguments, but there are no arguments. Bug?

SnapCracklins · Jul 3, 2022

Okay, I am slamming my head against the keyboard right now.

I made a stamina bar and made a method to make the animations for fading in and out stop whenever the animation player is finished. However, I am getting a "method expected zero arguments" error but there are NO ARGUMENTS. I also did not create the function with arguments. What is this and is it a bug?

extends Node2D

onready var _fade = $AnimationPlayer
onready var _bar = $AnimationPlayer/ProgressBar
onready var _warn = $AnimationPlayer/AnimatedSprite


func _ready():
	_fade.connect("animation_finished",self,"_stop_anim")
	_bar.value = Director._staminaJar
	_bar.raise()
	_bar.visible = false
	_warn.visible = false


func _process(_delta):
	_bar.value = Director._staminaJar
	
	if Director._emptyFlag == true:
		_warn.visible = true
	else:
		_warn.visible = false
	
	if _bar.value < 50:
		_update_bar()
	if _bar.value == 100:
		_hide_bar()


func _update_bar():
	_bar.visible = true
	_fade.play_backwards("bar_fade")
	
	
func _hide_bar():
	_fade.play("bar_fade")


func _stop_anim():
	_fade.stop()

DaveTheCoder · Jul 3, 2022

AnimationPlayer's "animation_finished" signal passes one argument, so the signal handler must declare that argument.
https://docs.godotengine.org/en/stable/classes/class_animationplayer.html#signals

Try changing:
func _stop_anim():
to:
func _stop_anim(_anim_name: String):

SnapCracklins · Jul 3, 2022

DaveTheCoder thanks for that. It's a bit frustrating that I have to use blank arguments on custom signals, but ah, that's learning. Works great now!