How to make a Dialogue System and apply it to a 3D scene? [ANSWERED]

Okay, I tested the code and made a few changes, since I had some syntax errors. Here is the code from the test/prototype project:

extends Area
var _is_player_in_area = false
# We will use the node name to detect if the node is the
# player or not. You may need to change this depending
# on how your game is setup and/or project requirements
export (String) var player_node_name = "Player"
# Custom signal (I’m not sure if the syntax here is correct...)
signal on_player_interact
# track if the player has interacted so we do not restart
# the interaction while the dialog is going
var _has_player_interacted = false

func _ready():
	connect("body_entered", self, "_on_body_entered")
	connect("body_exited", self, "_on_body_exited")
	
	connect("on_player_interact", self, "_test_function");

func _process(delta):
	if _is_player_in_area == true and _has_player_interacted == false:
		# In this example, the interact key is E, though you
		# probably want to change this with an action
		if Input.is_key_pressed(KEY_E):
			emit_signal("on_player_interact")
			_has_player_interacted = true
			# Interact prompt UI should, probably, be disabled here.

func _on_body_entered(other):
	if other.name == player_node_name:
		_is_player_in_area = true
		_has_player_interacted = false
		# If you have UI to show (like “press E to interact”)
		# then you could enable it here.

func _on_body_exited(other):
	if _is_player_in_area == true:
		if other.name == player_node_name:
			_is_player_in_area = false
			_has_player_interacted = false

func _test_function():
	print ("Interacted!");

The issue I was having was that the Godot didn't like " and I used the wrong name for the Input function. I was not able to reproduce the signal issue, it just worked, though to be fair I just connected the signal to simple function within the same script.

(Sorry about the delay! I thought I could get to it yesterday, but it didn't work out)

What if you try to delete and recreate the signal on the NPC node? I wonder if it isn't the NPC node name, from the error it seem like you might have created the signal on it before you renamed the node?

Here is what my scene looks like:

The reason it looks a little strange is because I slapped it into another prototype project for testing purposes. If you want, I can make a fresh project and upload it here to the forums if that would help.

Here you go! Hopefully it helps :smile: Link to Google Drive.

No worries on the delay. I'm glad the sample project was useful! :D

I assumed (not sure why to be honest) that the trigger and dialog were in the same script, in which case what I wrote above may work, but if they are separate, then adjustments will need to be made. Personally, I would keep them separate if possible, as then the triggers are more flexible.

That said, I'm not sure where the best place to put it would be. If the nodes are separate, then I might change it to something like this (untested):

The (new) trigger script:

extends Area
var _is_player_in_area = false

export (String) var player_node_name = "Player"

signal on_player_interact
# New signal for detecting further interactions
signal on_player_continued_interact

var _has_player_interacted = false

func _ready():
	connect("body_entered", self, "_on_body_entered")
	connect("body_exited", self, "_on_body_exited")
	
	# Optional:
	connect("on_player_interact", self, "_test_interact_function")
	connect("on_player_continued_interact", self, "_test_continued_interact_function")

func _process(delta):
	if _is_player_in_area == true:
		if Input.is_key_pressed(KEY_E):
			if _has_player_interacted == false:
				emit_signal("on_player_interact")
				_has_player_interacted = true
			else:
				emit_signal("on_player_continued_interact")

func _on_body_entered(other):
	if other.name == player_node_name:
		_is_player_in_area = true
		_has_player_interacted = false

func _on_body_exited(other):
	if _is_player_in_area == true:
		if other.name == player_node_name:
			_is_player_in_area = false
			_has_player_interacted = false

func _test_interact_function():
	print ("Interaction started!")
func _test_continued_interact_function():
	print ("Interaction continued!")

Then something like this in the dialog script itself:

Note: I am assuming the on_player_interact signal from the trigger is connected to a function called "on_trigger_interact" and on_player_continued_interact is connected to a function called "on_trigger_continued_interact"

var is_dialog_page_finished = false

func _on_trigger_interact():
	StartDialog()
func _on_trigger_continued_interact():
	if is_dialog_page_finished == false:
		RichTextLabel.set_visible_characters(RichTextLabel.get_total_character_count()+1)
		is_dialog_page_finished = true
	else:
		HandleNode()

I'm not totally sure the code will work though...

As a question: Isn't it a possible to connect the StartDialog() inside of the TRIGGER.gd with the Control node because we do have the signal that starts the conversation and will be able to sent the signal to the other code to display the text.

It should be possible. You should be able to connect the on_player_interact signal to start the conversation, either in the Godot editor or through code like get_node("Trigger").connect("on_player_interact", self, "function_name_here").

From what I can gather from the error message, the signal is looking for a function called _on_Trigger_on_player_interact but it does not exist. Maybe try changing the _on_player_interact function to _on_Trigger_on_player_interact and see if that works?