how do i change my skybox shader to use a panorama texture as base color?
shader_type sky;
render_mode use_quarter_res_pass;



group_uniforms sky;
	uniform vec3 top_color : source_color = vec3( 0.12, 0.30, 0.38 );
	uniform vec3 mid_color : source_color = vec3( 0.23, 0.50, 0.63 );
	uniform vec3 bottom_color : source_color = vec3( 0.54, 1.0, 0.93 );
	


group_uniforms sun; // First DirectionalLight3D will be the sun
	uniform vec3 sun_color : source_color = vec3( 1.0, 1.0, 1.0 );
	uniform float sun_intesity : hint_range(1.0, 10.0, 0.5) = 10.0;
	uniform float sun_size : hint_range( 0.01, 1.0 ) = 0.1;
	uniform float sun_blur : hint_range( 0.01, 5.0 ) = 2.0;

group_uniforms clouds;
	uniform float horizon_falloff: hint_range(0.0, 1.0, 0.1);
	uniform vec3 clouds_base_color : source_color = vec3( 0.88, 0.92, 0.98 );
	uniform vec3 clouds_dark_color : source_color = vec3( 0.54, 0.63, 0.67 );
	uniform float clouds_speed : hint_range( 0.0, 0.1, 0.005 ) = 0.01;
	uniform float clouds_scale : hint_range( 0.0, 4.0, 0.01 ) = 0.25;
	uniform float clouds_weight : hint_range( 0.0, 1.0, 0.01 ) = 0.5;
	uniform float clouds_blur : hint_range( 0.0, 1.0, 0.01 ) = 0.25;
	const mat2 m = mat2(vec2( 1.6, 1.2), vec2(-1.2, 1.6));


vec2 hash( vec2 p ) {
	p = vec2(dot(p, vec2(127.1, 311.7)), dot(p, vec2(269.5, 183.3)));
	return -1.0 + 2.0 * fract(sin(p) * 43758.5453123);
}
float noise( in vec2 p ) {
	const float K1 = 0.366025404; // (sqrt(3)-1)/2;
	const float K2 = 0.211324865; // (3-sqrt(3))/6;
	vec2 i = floor(p + (p.x + p.y)*K1);
	vec2 a = p - i + (i.x + i.y) * K2;
	vec2 o = (a.x > a.y) ? vec2(1.0, 0.0) : vec2(0.0, 1.0);
	vec2 b = a - o + K2;
	vec2 c = a - 1.0 + 2.0 * K2;
	vec3 h = max(0.5 - vec3(dot(a, a), dot(b, b), dot(c, c)), 0.0 );
	vec3 n = h * h * h * h * vec3(dot(a, hash(i + 0.0)), dot(b, hash(i + o)), dot(c, hash(i + 1.0)));
	return dot(n, vec3(70.0));
}
float noise2d( in vec2 x)
{
	float xhash = cos(x.x * 37.0);
	float yhash = cos(x.y * 57.0);
	return fract (415.92653 * (xhash + yhash));
}
float NoisyStarField( in vec2 vSamplePos, float fThreshhold)
{
	float StarVal = noise2d( vSamplePos );
    if ( StarVal >= fThreshhold )
        StarVal = pow( (StarVal - fThreshhold)/(1.0 - fThreshhold), 6.0 );
    else
        StarVal = 0.0;
    return StarVal;
}
float random(vec2 co)
{
    return fract( sin( dot( co.xy, vec2( 12.9898, 78.233 ) ) ) * 43758.5453 );
}
float fbm(vec2 n) {
	float total = 0.0, amplitude = 0.1;
	for (int i = 0; i < 7; i++) {
		total += noise(n) * amplitude;
		n = m * n;
		amplitude *= 0.4;
	}
	return total;
}
vec3 screen(vec3 base, vec3 blend){
	return 1.0 - (1.0 - base) * (1.0 - blend);
}
vec3 colorDodge( vec3 s, vec3 d )
{
	return d / (1.0 - s);
}

vec3 linearDodge( vec3 s, vec3 d )
{
	return s + d;
}
void sky()
{
	float time = TIME;
//	vec2 _sky_uv = EYEDIR.xz / sqrt( EYEDIR.y );
	float horizon = 1.0 - abs(-EYEDIR.y + horizon_falloff);
	float _eyedir_y = abs( sin( EYEDIR.y * PI * 0.5 ));
	float topmask = abs(sin(EYEDIR.y * PI * 0.2));
	//SKYCOLOR
	vec3 _sky_color = vec3(1);
	_sky_color = mix(bottom_color, mid_color, _eyedir_y );
	_sky_color = mix (_sky_color,top_color, topmask * 2.0);
	COLOR = _sky_color;

	
	//SUN
	float _sun_distance = 0.0;
	if( LIGHT0_ENABLED )
	{
		_sun_distance = distance( EYEDIR, LIGHT0_DIRECTION );
		// Bigger sun near the horizon
		float _sun_size = sun_size + cos( LIGHT0_DIRECTION.y * PI ) * sun_size * 0.25;
		// Finding sun disc and edge blur
		float _sun_amount = clamp(( 1.0 - _sun_distance / _sun_size ) / sun_blur, 0.0, 1.0 );
		vec3 _sun_color = sun_color;
		_sun_amount *= sun_intesity;
		
		COLOR = mix( COLOR, _sun_color, _sun_amount );
	}
	

	//CLOUDS & STARS
	if( EYEDIR.y > 0.0 )
	{
		//skyUVs
		vec3 normal = normalize(EYEDIR);
		vec3 plane_intersect = normal / (normal.y);
			
		vec2 p = plane_intersect.xz;
		p.y *= -1.0;
		vec2 uv = p;
		//STARFIELD
		vec3 starsColor = vec3(0);
		vec2 starTile   = floor( uv * 10.0 );
    	vec2 starPos    = fract( uv * 10.0 ) * 2.0 - 1.0;
    	float starRand  = random( starTile + vec2( 1.0, 5.0 ) );
    	starRand = starRand > 0.9 ? starRand : 0.0;
		COLOR += 0.4 * vec3( 1.2, 2.0, 1.2 ) * starRand * exp( -20.0 * length( starPos)) * horizon;
		time = time * clouds_speed;
		float q = fbm(uv * clouds_scale * 0.5);
		
		//ridged noise shape
		float r = 0.0;
		time = TIME * clouds_speed * 0.3;
		uv *= clouds_scale;
		uv -= q - time;
		float weight = 0.8;
		for(int i = 0; i < 8; i++){
			r += abs(weight*noise( uv ));
			uv = m*uv + time;
			weight *= 0.7;
		}
		
		//noise shape
		float f = 0.0;
		time = TIME * clouds_speed * 0.2;
		uv = p;
		uv *= clouds_scale;
		uv -= q - time;
		weight = 0.7;
		for(int i = 0; i < 8; i++){
			f += weight*noise( uv );
			uv = m*uv + time;
			weight *= 0.6;
		}
		
		f *= r + f;
		
		//noise colour
		float c = 0.0;
		time = TIME * clouds_speed * 1.0;
		uv = p;
		uv *= clouds_scale * 1.5;
		uv -= q - time;
		weight = 0.4;
		for(int i = 0; i < 7; i++){
			c += weight*noise( uv );
			uv = m*uv + time;
			weight *= 0.6;
		}
		
		//noise ridge colour
		float c1 = 0.0;
		time = TIME * clouds_speed * 3.0;
		uv = p;
		uv *= clouds_scale * 3.0;
		uv -= q - time;
		weight = 0.4;
		for (int i = 0; i < 7; i++){
			c1 += abs(weight*noise( uv ));
			uv = m*uv + time;
			weight *= 0.6;
		}
		
		c += c1;
		
		c = c * horizon;
		float clouds_value = clamp(smoothstep(clouds_weight, clouds_weight + clouds_blur, c),0.0,1.0);
		vec3 _clouds  = mix(clouds_base_color,  clouds_dark_color , clouds_value) * clouds_value ;
		vec3 skycolour = COLOR;
		
		COLOR = mix( skycolour, _clouds , clouds_value);
//		COLOR = screen(skycolour.rgb,_clouds.rgb);
		
		
	}
}