Encrypted save file from godot 3 doesn't work in godot 4.

belgian_street_lamp

Im using a simple file.store_var() and get_var() system. I can't open a save file from godot 3, and I heard that encryption method changed in godot 4. How can I open it now?

DaveTheCoder

I don't know if the encryption method changed, but:
store_var/get_var not compatible between Godot 3 and Godot 4 #73530

The issue could have been easily fixed back then, but the decision was made to retain the incompatibility.

belgian_street_lamp

DaveTheCoder hmm so what should I do know? I have now idea how to make both of these options, and I imagine there are lots of people who converted their games and have this issue. I can't just wipe out all of my players progress in one update...

DaveTheCoder

You could submit a new issue explaining your problem.

Others will probably encounter this problem, and someone will publish a standalone file converter, a Godot 4 plugin that reads Godot 3 files, or a Godot 3 plugin that writes Godot 4 files.

Another option is to build a custom version of Godot 4, with the enums changed as I suggested in that issue. But keeping it updated would be tedious.

belgian_street_lamp

DaveTheCoder ok ill submit an issue, just one question I found this code that converts config file data from godot 3 to 4. Can I modify it in a way that it converts file.get_var() data?

var filename = "user://file.cfg"
var password = "pass"

# read file
var f = FileAccess.open(filename, FileAccess.READ)
f.get_32() # magic, should be 0x43454447
f.get_32() # mode, ignore
f.get_buffer(16) # md5, you can check if decrypted data md5 hash match to verify it's ok
var len = f.get_64() # decrypted data length
var ds = len # encrypted data length, adjusted to block size
if ds % 16:
	ds += 16 - (ds % 16)
var data = f.get_buffer(ds)
var aes = AESContext.new()
aes.start(AESContext.MODE_ECB_DECRYPT, password.md5_text().to_ascii_buffer())
var decrypted = aes.update(data)
aes.finish()
decrypted.resize(len)
f.close()

# parse config
var cf = ConfigFile.new()
cf.parse(decrypted.get_string_from_utf8())

DaveTheCoder

belgian_street_lamp Can I modify it in a way that it converts file.get_var() data?

The issue I posted applies to store_var() and get_var(). It probably doesn't affect the more specific methods: store_16/get_16, store_32/get_32, etc. I haven't done a test, but if you can use those in place of store_var/get_var, that might be a solution.

DaveTheCoder

I don't think that will help in this case.

What about keeping your game in Godot 3 for now?

DaveTheCoder

On this topic, I just ran a test to check compatibility of ConfigFile between Godot 3 and Godot 4. I did the test using Godot 3.5.3-stable and Godot 4.2-dev6.

The test result:
Plain text files created by ConfigFile in either version are read correctly by the other version.
Encrypted files created by ConfigFile in either version are NOT readable by the other version. The result reported by ConfigFile is ERR_FILE_CORRUPT = 16.

Here's the code, if anyone wants to try it. The same code works in both Godot versions. You may need to change the path in the constant DIR.

extends Node

const I: int = 42
const F: float = 7.5
const B: bool = true
const S: String = "hello"
const V: Vector2 = Vector2(1.1, 2.2)
const A: Array = [3, 4]
const D: Dictionary = {"a": 15, "b": 30}

const DATA: Dictionary = {
	"I": I,
	"F": F,
	"B": B,
	"S": S,
	"V": V,
	"A": A,
	"D": D,
}

const DIR: String = "/tmp/godot_configfile_test/"
const PATH_GODOT_3: String = DIR + "godot3.txt"
const PATH_GODOT_3_ENCRYPTED: String = DIR + "godot3_encrypted.dat"
const PATH_GODOT_4: String = DIR + "godot4.txt"
const PATH_GODOT_4_ENCRYPTED: String = DIR + "godot4_encrypted.dat"
const PASSWORD: String = "godot"


func _ready() -> void:
	var version: int = Engine.get_version_info()["major"]
	print_debug("Godot version=", version)

	match version:
		3:
			write_file(PATH_GODOT_3)
			write_file(PATH_GODOT_3_ENCRYPTED, true)
		4:
			write_file(PATH_GODOT_4)
			write_file(PATH_GODOT_4_ENCRYPTED, true)
	
	read_and_test_file(PATH_GODOT_3)
	read_and_test_file(PATH_GODOT_3_ENCRYPTED, true)
	read_and_test_file(PATH_GODOT_4)
	read_and_test_file(PATH_GODOT_4_ENCRYPTED, true)


func write_file(path: String, encrypted: bool = false) -> void:

	var config_file: ConfigFile = ConfigFile.new()

	config_file.set_value("section", "key", DATA)

	var err: int

	if encrypted:
		err = config_file.save_encrypted_pass(path, PASSWORD)
	else:
		err = config_file.save(path)

	if err == OK:
		print_debug("Successfully wrote file '%s'" % path)
	else:
		print_debug("Failed to write file '%s', error=%d" % [path, err])


func read_and_test_file(path: String, encrypted: bool = false) -> void:

	var config_file: ConfigFile = ConfigFile.new()
	
	var err: int

	if encrypted:
		err = config_file.load_encrypted_pass(path, PASSWORD)
	else:
		err = config_file.load(path)

	if err == OK:
		print_debug("Successfully read file '%s'" % path)
	else:
		print_debug("Failed to read file '%s', error=%d" % [path, err])
		return

	var data: Dictionary = config_file.get_value("section", "key")

	if data == null:
		print_debug("Failed to extract data from file")
		return
	
	print_debug("data=", data)
	
	var ok: bool = true
	
	if not data is Dictionary:
		print_debug("Data test failed: data type") 
		ok = false
	
	if not data.has_all(DATA.keys()):
		print_debug("Data test failed: missing key(s)") 
		ok = false

	if not (data["I"] is int and data["I"] == I):
		print_debug("Data test failed: I") 
		ok = false

	if not (data["F"] is float and data["F"] == F):
		print_debug("Data test failed: F") 
		ok = false

	if not (data["B"] is bool and data["B"] == B):
		print_debug("Data test failed: B") 
		ok = false

	if not (data["S"] is String and data["S"] == S):
		print_debug("Data test failed: S") 
		ok = false

	if not (data["V"] is Vector2 and data["V"].x == V.x and data["V"].y == V.y):
		print_debug("Data test failed: V") 
		ok = false

	if not (data["A"] is Array and data["A"].size() == A.size()\
			and data["A"][0] == A[0] and data["A"][1] == A[1]):
		print_debug("Data test failed: A") 
		ok = false

	if not (data["D"] is Dictionary and data["D"].size() == D.size()\
			and data["D"]["a"] == D["a"] and data["D"]["b"] == D["b"]):
		print_debug("Data test failed: D") 
		ok = false

	if ok:
		print_debug("All data tests passed for file '%s'" % path)

I just tried the code posted above by belgian_street_lamp, in Godot 4. It successfully reads an encrypted file created by ConfigFile in Godot 3.

belgian_street_lamp

DaveTheCoder still no solution, can’t go back to godot 3 because I deleted all old plugins, exports etc, and after 1 month of work everything is ready in godot 4 except this. To make matters worse I need to upload my game to google play store by the end of this month! (And it usually takes them 1-3 weeks to upload it). The issue I posted didn’t help at all. I am screwed 😭

DaveTheCoder

I'll link the issue here for reference: Loading encrypted save data from godot 3 in godot 4 doesn’t work #83034

belgian_street_lamp

DaveTheCoder I think i will give up. I don’t know what to do anymore and I don’t have any more time 🙁

DaveTheCoder

Did you write the save/load code for your game? If you were able to do that, you should be able to change it to solve this problem.

If you make an attempt to do it, you'll probably get help. But not if you give up without trying.

belgian_street_lamp

DaveTheCoder umm I’m not sure i understand, what save/load code?

DaveTheCoder

The "simple file.store_var() and get_var() system" you mentioned in the first post.

belgian_street_lamp

DaveTheCoder Yeah it is already written but that doesnt change the fact that saves from godot 3 dont work.? Wait change it for what?

DaveTheCoder

It sounds like your Godot 3 game is currently published, and you need to publish the Godot 4 version by the end of the month?

belgian_street_lamp

DaveTheCoder yup, because of google play.

DaveTheCoder

Can you release updates to the Godot 3 version, such as bug fixes, using the same version of Godot 3?

belgian_street_lamp

So you say I should update my godot 3 game to use config file and then update it to godot 4? But what if someone skips the update...?

belgian_street_lamp

belgian_street_lamp but updating the godot 3 version seems to be the best choice so far :/

belgian_street_lamp

Google play console: