in need of a shader wizard

DJM

Megalomaniak i have no idea, i allready tried setting that to 1. i started with the shader spacecloud wrote.

DJM

actually deleting this line made the shader work
triplanar_pos *= vec3(1.0,-1.0, 1.0);
dont know why, but it works fine now.

Megalomaniak

I was honestly going by gut feeling there, so if it works now, great. But there could still be a chance of some nasty surprise I suppose, since I was just giving a quick glance over the code, it's not as if I made a quick test model and brought it into godot to test the actual shader out on it.

DJM

i was wrong, again, bah....
ive managed to get the normal lighting working correctly but the normals are now way too saturated
ive made a zip of my terrain and current state of the shader.
feel free to have a look.

also, why is it when u zip a godot project its larger than the actual files that are in the project folder?

Megalomaniak

Because there's likely already some compression involved. I'll take a look at the scene when I have a bit more free time, hopefully some time tomorrow.

Megalomaniak

Ok, I'm looking at it. But whats your current specific problem? Lowering blend_sharpness below 1.0?

DJM

Megalomaniak thnx for having a look, are u using alpha12?
the normals are way to 'hard' now .
if u lower blend_sharpness the triplanar blending gets messed up, which is not what i want

Megalomaniak

Yes alpha 12. Lowering blend sharpness what I see looks like the detail textures mapping/"UV"s are messed. Like the texture isn't repeating correctly.

Also off topic but interesting to note: the image is displayed wrong in my browser. Gamma is off. Hmm.

DJM

yeah blend_sharpness variable should always be just 1 i guess,
dont know why its exposed as a variable, this gives the same result
power_normal = abs(NORMAL);
i think, the fix lies in these lines of the shader>

power_normal = pow(abs(NORMAL),vec3(blend_sharpness));
power_normal /= dot(power_normal,vec3(1.0));

but im just guessing.

Megalomaniak

Ok, I removed all the detail blending and the issue remains so it's in that blend() function.

DJM

this was the only working method i found on an example on 'shadertoy'

n1 += vec3(0, 0, 1);
n2 *= vec3(-1, -1, 1);
	
return normalize(n1*dot(n1, n2)/n1.z - n2);

https://www.shadertoy.com/view/4t2SzR

Megalomaniak

DJM this was the only working method i found on an example on 'shadertoy'

 n1 += vec3(0, 0, 1);
 n2 *= vec3(-1, -1, 1);
 	
 return normalize(n1*dot(n1, n2)/n1.z - n2);

It's not that, I already ruled that and now the blend() out. So it's just the triplanar mapping as far as i can tell. It's also entirely possible that the issue involves some bug in godot 4 rendering. I tried creating a standard material with triplanar mapping and converting into shader for comparison. The code seems pretty much the same as I suspected, so...

DJM

i also tried making a 'fake wind' shader, but its useless, as the editor becomes really, really slow.
and the vertices dont get displaced correctly, it seems they get calculated from the pivot point of the mesh

shader_type spatial;
render_mode blend_mix, depth_prepass_alpha, cull_disabled, diffuse_burley, specular_schlick_ggx;
uniform float alphatreshold;
uniform float strenght : hint_range(0.0, 1.0, 0.05);
uniform float speed : hint_range(0.0, 1.0, 0.1);

uniform sampler2D colortex : source_color,filter_linear_mipmap,repeat_disable;
uniform sampler2D normaltex :  hint_roughness_normal,filter_linear_mipmap,repeat_disable;
uniform sampler2D roughnesstex : hint_roughness_gray,filter_linear_mipmap,repeat_disable;



void vertex() {
	
	VERTEX.x += sin(TIME * speed + VERTEX.x + VERTEX.z ) * strenght * COLOR.g;
	VERTEX.y += sin(TIME * speed + VERTEX.y + VERTEX.x ) * strenght * COLOR.g;
	VERTEX.z += sin(TIME * speed + VERTEX.z + VERTEX.y ) * strenght * COLOR.g;

}

void fragment() {
	
	ALPHA = texture(colortex,UV).a;
	ALPHA_SCISSOR_THRESHOLD = alphatreshold;
	ALBEDO= texture(colortex,UV).rgb;
	NORMAL_MAP = texture(normaltex,UV).rgb;
	METALLIC = 0.0;
	SPECULAR = 0.5;
	ROUGHNESS = texture(roughnesstex,UV).r;
	
}

DJM

Megalomaniak should i open an issue on git?

Megalomaniak

Not sure yet. I'll try and hammer out a custom shader from scratch to test further, in the meanwhile you can try setting up a test scene in godot 3 and copy and paste the shader into there, see how it does there.

spacecloud

I think i got the normals fixed


// Whiteout normal blending, example at https://blog.selfshadow.com/publications/blending-in-detail
vec3 normalblend(vec3 n1, vec3 n2)
{
	n1 = n1 * 2.0 - 1.0;
	n2 = n2 * 2.0 - 1.0;
	return normalize(vec3(n1.xy + n2.xy, n1.z * n2.z)) + vec3(0.5, 0.5, 1.0);
}

This doubles the NORMAL_MAP_DEPTH, so that has to be 0.5 instead of 1.0 if you use this.

DJM

spacecloud tnx! that did it!
heres' the working shader



shader_type spatial;
render_mode blend_mix, depth_draw_opaque, cull_back, diffuse_burley, specular_schlick_ggx;
uniform float blend_sharpness = 1.0;
uniform float normal_scale = 1.0;

uniform vec3 texture1_scale = vec3(1.0);

uniform sampler2D texture1_albedo : source_color,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture1_normal : hint_normal,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture1_roughness : hint_roughness_gray,filter_linear_mipmap,repeat_enable;


uniform vec3 texture2_scale = vec3(1.0);

uniform sampler2D texture2_albedo : source_color,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture2_normal : hint_roughness_normal,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture2_roughness : hint_roughness_gray,filter_linear_mipmap,repeat_enable;


uniform vec3 texture3_scale = vec3(1.0);

uniform sampler2D texture3_albedo : source_color,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture3_normal : hint_roughness_normal,filter_linear_mipmap,repeat_enable;
uniform sampler2D texture3_roughness : hint_roughness_gray,filter_linear_mipmap,repeat_enable;

uniform sampler2D detailtexture : hint_roughness_gray,filter_linear_mipmap,repeat_enable;
uniform sampler2D detailroughness : hint_roughness_gray,filter_linear_mipmap,repeat_enable;
uniform sampler2D detailnormal : hint_roughness_normal,filter_linear_mipmap,repeat_enable;

uniform vec3 detail_scale = vec3(1.0);
varying vec3 power_normal;
varying vec3 triplanar_pos;
void vertex() {
	TANGENT = vec3(0.0,0.0,-1.0) * abs(NORMAL.x);
	TANGENT += vec3(1.0,0.0,0.0) * abs(NORMAL.y);
	TANGENT += vec3(1.0,0.0,0.0) * abs(NORMAL.z);
	TANGENT = normalize(TANGENT);
	BINORMAL = vec3(0.0,1.0,0.0) * abs(NORMAL.x);
	BINORMAL += vec3(0.0,0.0,-1.0) * abs(NORMAL.y);
	BINORMAL += vec3(0.0,1.0,0.0) * abs(NORMAL.z);
	BINORMAL = normalize(BINORMAL);
	power_normal = pow(abs(NORMAL),vec3(blend_sharpness));
	triplanar_pos = VERTEX;
	power_normal /= dot(power_normal,vec3(1.0));
	triplanar_pos *= vec3(1.0,-1.0, 1.0);


	
}
vec3 triplanar_texture(sampler2D p_sampler, vec3 p_triplanar_pos) {
	vec3 samp = vec3(0.0);
	samp += texture(p_sampler,p_triplanar_pos.xy).xyz * power_normal.z;
	samp += texture(p_sampler,p_triplanar_pos.xz).xyz * power_normal.y;
	samp += texture(p_sampler,p_triplanar_pos.zy).xyz * power_normal.x;
	return samp;
}

vec3 blend(vec3 texture1, vec3 texture2, vec3 texture3, vec4 color){
	return ((texture1 * color.r) + (texture2 * color.b) + (texture3 * color.g)).rgb;
}

vec3 normalblend(vec3 n1, vec3 n2)
{
	n1 = n1 * 2.0 - 1.0;
	n2 = n2 * 2.0 - 1.0;
	return normalize(vec3(n1.xy + n2.xy, n1.z * n2.z)) + vec3(0.5, 0.5, 1.0);
}
void fragment() {
	vec3 albedo_texture = (blend(triplanar_texture(texture1_albedo, triplanar_pos * texture1_scale), triplanar_texture(texture2_albedo, triplanar_pos * texture2_scale) , triplanar_texture(texture3_albedo, triplanar_pos * texture3_scale), COLOR)) * triplanar_texture(detailtexture, triplanar_pos * detail_scale);
	ALBEDO = albedo_texture.rgb;
	vec3 orm_texture = (blend(triplanar_texture(texture1_roughness, triplanar_pos * texture1_scale), triplanar_texture(texture2_roughness, triplanar_pos * texture2_scale), triplanar_texture(texture3_roughness, triplanar_pos * texture3_scale), COLOR))* triplanar_texture(detailroughness, triplanar_pos * detail_scale);
	AO = 1.0;
	ROUGHNESS = orm_texture.r;
	METALLIC = 0.0;
	NORMAL_MAP = normalblend(blend(triplanar_texture(texture1_normal, triplanar_pos * texture1_scale), triplanar_texture(texture2_normal, triplanar_pos * texture2_scale), triplanar_texture(texture3_normal, triplanar_pos * texture3_scale), COLOR),triplanar_texture(detailnormal, triplanar_pos * detail_scale));
	NORMAL_MAP_DEPTH = normal_scale;
}

any idea why my vertex offset shader is bad?

spacecloud

I don't know other than that VERTEX is always relative to the pivot, so that might be messing up the displacement.
If all transforms were applied in blender the pivot is at 0, 0, 0.

Megalomaniak

it's not worldspace without the skip_vertex_transform and MODELVIEW_MATRIX or perhaps MODEL_MATRIX multiplication iirc.

https://docs.godotengine.org/en/latest/tutorials/shaders/shader_reference/spatial_shader.html#vertex-built-ins

edit: nevermind, theres something simpler:

They can optionally be presented in world space by using the world_vertex_coords render mode.

DJM

Megalomaniak
u were right, using world_vertex_coords fixed it, tnx!
render_mode blend_mix, depth_prepass_alpha, cull_back, diffuse_burley, specular_schlick_ggx,world_vertex_coords;

DJM

i want the vertices painted vertex color green to be offsetted.

but indeed the leafplanes are one mesh with the pivot at the center

« Previous Page Next Page »