(ECS) What ways are there to check for a child of certain class?

Rainfollower

TL;DR:
Now I check the existence of certain child by node name: has_node("HealthComponent") where HealthComponent is a name of a node
Is there any way to check this by child's class? Something like: includes(HealthComponent) where HealthComponent is a class

In my project I am trying to stay in the philosophy of Entity Component System. It seems to go well with Godot Nodes.
It means that every 'kind of functionality' is its own node, that can be attached to any number of things and still provide the same functionality.

So. To check if this entity has this kind of functionality I must check, whether it has a certain child Node of the required class. And to do that, I currently use has_node(). Like this:

#attaching a signal to update unit's target in attack component
if unit_instance.has_node("AttackComponent"):
	game_scene.select_attack_target.connect(unit_instance.attack_component.update_attack_target)

but it feels... clunky. Is there a better way, maybe?

How do I check if the target 'entity' has a child node of a certain class?

Here's how I built my system:

Every Component declared as its own class.
Every entity that has components, has a variable for each one.

But that's pretty lot of manual work when creating or changing any kind of game entity, or accessing their functionalities from other components.

extends CharacterBody2D
class_name Unit

@export var selection_component : SelectionComponent
@export var movement_component : MovementComponent
@export var abilityProgress : ProgressBar
@export var nav_agent : NavigationAgent2D
@export var health_component : HealthComponent
@export var attack_component : AttackComponent

My own idea (does not feel very good to me):

A kind of global list (Enum?) of all existing component classes (but how to pass them as class names?)
In each entity, an array of the enum length. Array[n], where n is a value taken from enum by class name
Array filled on _ready() via get_children() and checking them against list of classes in Enum
A function that returns a child from the array (if the class fits) or null

Does this look any realistic?..

MikeCL

Rainfollower

Not entirely sure what you mean. But to check if a node is a certain class you can do:

if my_node is <node type/class>:
    {...your logic}

And if you want to check for methods you can also check with has_method("your_method") and I believe it should return a boolean

JoshuaCC

One way could be to follow a service locator pattern and have a dictionary on the unit which has all the components mapped as Class : Object. But whatever feels most natural and suitable based on the needs for your project would be best.
Service Locator: https://en.wikipedia.org/wiki/Service_locator_pattern

Example below

Unit Script

var components: Dictionary = {}
func register_component(component_class, _component):
    components[component_class] = _component

func unregister_component(component_class):
    var _component = components.get(component_class, null)
    if _component:
        _component.remove() # replace with whatever your cleanup function is, if you have one
        components.erase(component_class)

func get_component(component_class):
    return components.get(component_class, null)

func has_component(component_class):
    return components.has(component_class)

Component Script

class_name AttackComponent

func _ready() -> void:
    parent.register_component(AttackComponent, self)

func remove() -> void:
    self.queue_free()

func update_attack_target() -> void:
    pass # your logic here

Other Script

func do_something() -> void:
    var attack_component: AttackComponent = unit_instance.get_component(AttackComponent)
    if attack_component:
        game_scene.select_attack_target.connect(attack_component.update_attack_target)

Rainfollower

JoshuaCC wow, that's a lot! And seems pretty close to what I was trying to achieve. Thank you very much.

One more question if I may. I see you pass AttackComponent class name as an argument.

func _ready() -> void:
    parent.register_component(AttackComponent, self)

Do you pass it as type? Or as something esle? I do not underatnd how this works. You see, when I try to make something like

var foo = AttackComponent
var bar = AttackComponent.new()
print_debug(bar is foo)

it says that foo does not contain a type.

Could you maybe point me towards some place to read more about this? I am not sure where to look in GDscript docs for such things. There's a good reference to built-in classes and their methods/properties, but I don't understand how to look for such very 'core' things.

JoshuaCC

Rainfollower

Yep I pass the class name (type) as the 1st argument and the instance of that type as the second so it would be in the following format:

register_component(<Type>, <Instance>)
get_component(<Type>) # Returns the <Instance>

For the below the reason gives an error indicating foo is not a type is because the "is" keyword expects a compile-time class and not a runtime variable:

# Problem Code
var foo = AttackComponent # Foo is created as a "Script" which is a class stored as a resource e.g. var foo: Script
var bar = AttackComponent.new()
print_debug(bar is foo) # Foo is no longer a type but it is a Resource

# Solution 1 (Recommended where dynamic comparison is not needed):
var bar = AttackComponent.new()
print_debug(bar is AttackComponent) # AttackComponent is a direct reference to the compile-time class

# Solution 2 (Recommended where dynamic comparison is needed):
var foo = AttackComponent
var bar = AttackComponent.new()
print_debug(is_instance_of(bar, foo)) # is_instance_of can compare dynamic runtime classes allowing this to work

# Solution 3:
var foo = AttackComponent
var bar = AttackComponent.new()
print_debug(bar.get_script() == foo) # Foo is a script reference to the class, bar.get_script() gets the class script, therefore they are the same.

# more info
AttackComponent # Static Class Name
var foo: Script = AttackComponent # Script class containing references to the static class

As for the methods of creating the component registry and other core systems, that would fall more under software/game dev architecture and design patterns which I usually gain knowledge for through multiple sources depending on the scenario e.g. Blogs/YouTube/ChatGPT.

I did find this which I've had a quick read of and seems to cover some important topics though it is in a different language, the principals can be used:

is_instance_of reference:
https://docs.godotengine.org/en/stable/classes/class_%40gdscript.html#class-gdscript-method-is-instance-of

Script Class reference:
https://docs.godotengine.org/en/stable/classes/class_script.html#class-script

get_script() reference (Inherited by Object):
https://docs.godotengine.org/en/stable/classes/class_object.html#class-object-method-get-script

Rainfollower

JoshuaCC oh thanks a lot! Those are exactly the things I lack in my casual approach to learning to program.