I don't understand this error. (Answered)

Mentiras

As before this project is from HeartBeast's ARPG tutorial (my copy that I try new things on while waiting for the next video).

I am attempting to randomize my minotaur's attacks. When I try and loop the state, from STOP back to searching for a player, I get this error, "Invalid Call. Nonexistent function 'randi_range' in base 'int'." All I have to do is take out the seek_player function in the STOP state and it works (but doesn't loop back).

extends KinematicBody2D

const EnemyDeathEffect = preload("res://Effects/EnemyDeathEffect.tscn")

var rng = RandomNumberGenerator.new()
var press = 0

export var ACCELERATION = 300
export var MAX_SPEED = 50
export var FRICTION = 200

enum {
	IDLE,
	WANDER,
	CHASE,
	ATTACK,
	STOP
}

var velocity = Vector2.ZERO
var knockback = Vector2.ZERO
var state = CHASE

onready var stats = $Stats
onready var playerDetectionZone = $PlayerDetectionZone
onready var sprite = $AnimatedSprite
onready var hurtbox = $HurtBox
onready var label = $Label
onready var hit = $Hit

func _ready():
	rng.randomize()

func _physics_process(delta: float) -> void:
	knockback = knockback.move_toward(Vector2.ZERO, FRICTION * delta)
	knockback = move_and_slide(knockback)
	
	match state:
		IDLE:
			velocity = velocity.move_toward(Vector2.ZERO, FRICTION * delta)
			seek_player()
			sprite.play("Idle")
			label.text = "IDLE"
		WANDER:
			pass
		CHASE:
			var player = playerDetectionZone.player
			if player != null:
				var direction = (player.global_position - global_position).normalized()
				velocity = velocity.move_toward(direction * MAX_SPEED, ACCELERATION * delta)
				sprite.play("Run")
				label.text = "CHASE"
				if (player.global_position.length() - global_position.length()) <= 38:
					state = ATTACK
			else:
				state = IDLE
				
			sprite.flip_h = velocity.x < 0
		ATTACK:
			label.text = "ATTACK"
			rng = (rng.randi_range(16, 1) * press) - press
			if rng < 20:
				print("attack1"+' ', rng)
				sprite.play("Jab")
				state = STOP
			if rng > 20:
				print("attack2"+' ', rng)
				sprite.play("OverHead")
				state = STOP
			else:
				print("attack3"+' ', rng)
				sprite.play("Whirl")
				state = STOP
		STOP:
			velocity = velocity.move_toward(Vector2.ZERO, FRICTION * delta)
			sprite.play("Idle")
			seek_player()

	velocity = move_and_slide(velocity)
			
func seek_player():
	if playerDetectionZone.can_see_player():
		state = CHASE
		
func _input(event: InputEvent) -> void:
	if event is InputEventKey and event.pressed and not event.is_echo():
		press += 1
		if press == 4:
			press = 1
	
func _on_HurtBox_area_entered(area: Area2D) -> void:
	hit.play("Hit")
	stats.health -= area.damage
	knockback = area.knockback_vector * 120
	hurtbox.create_hit_effect()

func _on_Stats_no_health() -> void:
	queue_free()
	var enemyDeathEffect = EnemyDeathEffect.instance()
	get_parent().add_child(enemyDeathEffect)
	enemyDeathEffect.global_position = global_position

Megalomaniak

Can you provide us with the code for $playerDetectionZone node? Seems to me the issue is likely stemming from there..?

edit: could be as simple as giving the seek_player() function a graceful way to fail, that is put an else: with some login into it?

    else:
        state = IDLE

for an example? Not sure though.

Mentiras

Player Detection Zone node code:

extends Area2D

var player = null 

func can_see_player():
	return player != null

func _on_PlayerDetectionZone_body_entered(body: Node) -> void:
	player = body

func _on_PlayerDetectionZone_body_exited(_body: Node) -> void:
	player = null

Tried the else: state = IDLE, same error =)

SIsilicon28

This line is causing the issue.

rng = (rng.randi_range(16, 1) * press) - press

In the beginning, rng was a RandomNumberGenerator object, but according to this line, it gets set as an integer. Which is why the error stating that an integer is trying to call randi_range().

Mentiras

I use the same setup to randomize "loot" when bushes are cut, why does it give me a problem here?

SIsilicon28

Maybe cause random number is only generated once in that script per bush. If it were to try it a second time, then it would throw the same error.

You see, the second time it tries to call that function, rng would have been an integer due to that line last time it was used. You shouldn't assign an integer, or anything else for that matter, to the number generator.

TwistedTwigleg

Yeah, looking at the code, the issue appears to be what @SIsilicon28 said. As for why it is not giving you the issue there, that is a good question.

My hunch is that in the randomized loot, you might be defining a new local variable called rng, and so Godot overrides the local variable rather than the class variable (the RandomNumberGenerator object). For example, the following code works, though is not advisable (untested):

extends Node
var string = "Hello world!"
func _ready():
	var string = 10
	print (string + 10)

Which should execute correctly, but it will print 20 rather than cause an error by trying to add 10 to a string. I'm guessing something like that is happening with rng in the randomized loot, though I'm just guessing.

I'd recommend changing the line so that it uses a new local variable with a unique name, like var rng_attack. Then you can use rng to get the random number:

var rng_attack = (rng.randi_range(16, 1) * press) - press

Then all you have to do is change the code in that chunk to use rng_attack rather than rng and that should fix the issue.

Mentiras

Thank you, everyone. I appreciate the responses. Changing it to a variable with a unique name worked, and that was indeed the case on the bush, it was only called once.

SIsilicon28

Great! The answer can be marked as accepted then. :)

Megalomaniak

Interestingly you might have avoided this if you were using static typing over dynamic. https://docs.godotengine.org/en/stable/getting_started/scripting/gdscript/static_typing.html