Moving with mouse AND keys

Cernu

Hi,

I am curently using a "mouse click, go to mouse click" movement system.

    	dir = ((get_global_mouse_position() - position).normalized())
    	look_at (get_global_mouse_position())
    	if(Input.is_action_pressed("click")):
    			move_and_slide(dir * speed)

I would like to add a key_right and key_left movement, that would make me go right or left, based on the direction I am curently facing.

I know I should take dir as a reference, instead of x, but I don't know how to do that (I am using dir.x, but it moves me on the x axis...) ... Any help please ?

TwistedTwigleg

This topic has code snippets I wrote on moving based on the rotation of a sprite. I think it should work with the direction vector as well, you just might need to make a few tweaks.

If the code in those snippets do not work, let me know and I can do some tests. (side note: Welcome to the forums!)

Cernu

Thanks, but I couldn't use your code. After some head banging, the closest thing I could come to get what I want is this:

    	if Input.is_action_pressed('ui_right'):
    		position += Vector2(0,10).rotated(rotation)
    
    	if Input.is_action_pressed('ui_left'):
    		position += Vector2(0,10).rotated(rotation)

However, the closer the character gets to the mouse, the sharper the rotation, to the point of spinning.

I don't want the character to rotate, I want it to slide left and right. I will give it another shot tomorrow.

TwistedTwigleg

Hmm, I have not tested yet, but this might move the character left/right relative to the dir variable:

dir = ((get_global_mouse_position() - position).normalized())
look_at (get_global_mouse_position())

if (Input.is_action_pressed("ui_right")):
	var right_direction = dir.rotated(-PI)
	move_and_slide(right_direction * speed)
if (Input.is_action_pressed("ui_left")):
	var left_direction = dir.rotated(PI)
	move_and_slide(left_direction * speed)

if (Input.is_action_pressed("click")):
	move_and_slide(dir * speed)

I'll make a quick prototype project once I have the time, but off the top of my head I think that code snippet should hopefully work. Left/Right might be flipped though, I always forgot the direction Godot uses in 2D for rotation.

Edit: The following code works in my test project:

func _physics_process(delta):
	
	var dir = ((get_global_mouse_position() - position).normalized())
	var speed = 100;
	
	look_at (get_global_mouse_position())
	if (Input.is_action_pressed("ui_right")):
		var right_direction = dir.rotated(PI/2)
		move_and_slide(right_direction * speed)
	if (Input.is_action_pressed("ui_left")):
		var left_direction = dir.rotated(-PI/2)
		move_and_slide(left_direction * speed)
	
	if (Input.is_action_pressed("click")):
		move_and_slide(dir * speed)

I had to make a few changes from the above. PI needs to be divided by two, and the negative needs to be on the left, not the right.

Hopefully this helps :smile:

Cernu

Your snippet does the same thing as mine. However, what I am looking for is that the game gets the dir, and moves the player not on the basic x and y, but with the player as origin . so the new x would be the players position at 90 degrees, and the why would be at 180 degrees. So I tried to look into Transform 2D, but I can't get it to work.

TwistedTwigleg

I'm a tad confused on how you are wanting to move the player. If possible, can you link to a video and/or picture and/or game that shows the type of movement you are wanting to achieve? I am just having a hard time wrapping my head around the issue.

To move the character like in the game Enter the Gungeon, for example, you want to not use the rotation/direction of the player, and instead move the player relative to the origin of the world. The following code should move the character relative to the origin of the world, like the movement seen in games like Enter the Gungeon:

var dir = ((get_global_mouse_position() - position).normalized())
var speed = 500;

look_at (get_global_mouse_position())

if (Input.is_action_pressed("ui_right")):
	move_and_slide(Vector2.RIGHT * speed)
if (Input.is_action_pressed("ui_left")):
	move_and_slide(Vector2.LEFT * speed)
if (Input.is_action_pressed("ui_up")):
	move_and_slide(Vector2.UP * speed)
if (Input.is_action_pressed("ui_down")):
	move_and_slide(Vector2.DOWN * speed)

if (Input.is_action_pressed("click")):
	move_and_slide(dir * speed)

If you want to move the player relative to it's rotation but you do not want the circular looking movement, then you need store the reference direction before moving so that as the player moves, it is not effected by the change in rotation. The reason the circular movement is occurring is because look_at is being called every frame, which changes the rotation of the sprite as it moves. Same with direction, as the player moves the vector pointing to the mouse changes, changing the angle to the mouse position.

There are two relatively easy ways to work around this. The first is not calling look_at every frame and using the rotation to get the left/right vectors:

var dir = ((get_global_mouse_position() - position).normalized())
var speed = 500;

if (Input.is_action_pressed("ui_right")):
	var right_direction = Vector2(cos(rotation + PI/2), sin(rotation + PI/2));
	move_and_collide(right_direction * speed * delta)
if (Input.is_action_pressed("ui_left")):
	var left_direction = Vector2(cos(rotation - PI/2), sin(rotation - PI/2));
	move_and_collide(left_direction * speed * delta)
if (Input.is_action_pressed("ui_up")):
	var forward_direction = Vector2(cos(rotation), sin(rotation));
	move_and_slide(forward_direction * speed)
if (Input.is_action_pressed("ui_down")):
	var forward_direction = Vector2(cos(rotation), sin(rotation));
	move_and_slide(-forward_direction * speed)

if (Input.is_action_pressed("click")):
	look_at (get_global_mouse_position())
	move_and_slide(dir * speed)

The second way is to store the rotation direction in a class variable, and update that class variable when the player clicks the mouse:

var movement_direction = Vector2.ZERO;
func _physics_process(delta):
	
	var dir = ((get_global_mouse_position() - position).normalized())
	var speed = 500;
	
	look_at (get_global_mouse_position())
	
	if (Input.is_action_pressed("ui_right")):
		var right_direction = movement_direction.rotated(PI/2)
		move_and_collide(right_direction * speed * delta)
	if (Input.is_action_pressed("ui_left")):
		var left_direction = movement_direction.rotated(-PI/2)
		move_and_collide(left_direction * speed * delta)
	if (Input.is_action_pressed("ui_up")):
		move_and_slide(movement_direction * speed)
	if (Input.is_action_pressed("ui_down")):
		move_and_slide(-movement_direction * speed)
	
	if (Input.is_action_pressed("click")):
		movement_direction = dir;
		move_and_slide(dir * speed)

Hopefully one of those code snippets helps!