Problem With 2D Collision

d4v3y_5c0n3s

(hopefully the GIF works) I am having an issue where the character collides with the ground and stops, but doesn't register that it is on the ground (and thus, cannot be moved.) I tried to copy the Dynamic Platformer Demo in order to avoid issues like this. :disappointed: The code for the player is below:

extends RigidBody2D

#This code is heavily based on one of the 2D platformer demos
#for Godot Engine.  The demo in question was created by
#Juan Linietsky.  This game is built more for my own amusement
#and learning than anything else.  It has been a while since I
#worked with Godot; so I feel that this would be a good way to
#refresh me on the program somewhat.

var anim = ""
var siding_left = false
var jumping = false
var stopping_jump = false
var shooting = false

var WALK_ACCEL = 800.0
var WALK_DEACCEL = 800.0
var WALK_MAX_VELOCITY = 200.0
var AIR_ACCEL = 200.0
var AIR_DEACCEL = 200.0
var JUMP_VELOCITY = 460
var STOP_JUMP_FORCE = 900.0

var MAX_AIRBORNE_TIME = 0.15

var airborne_time = 1e20
var shoot_time = 1e20

var MAX_SHOOT_POSE_TIME = 0.3

var bullet = preload("bullet.tscn")
var floor_h_velocity = 0.0
onready var enemy = load("res://enemy.tscn")

func _integrate_forces(s):
	var lv = s.get_linear_velocity()
	var step = s.get_step()
	
	var new_anim = anim
	var new_siding_left = siding_left
	
	#controls go here
	var move_left = Input.is_action_pressed("move_left")
	var move_right = Input.is_action_pressed("move_right")
	var jump = Input.is_action_pressed("jump")
	var shoot = Input.is_action_pressed("shoot")
	var spawn = Input.is_action_pressed("spawn")
	
	if spawn:
		var e = enemy.instance()
		var p = position
		p.y = p.y - 100
		e.position = p
		get_parent().add_child(e)
	
	#undos previous floor velocity
	lv.x -= floor_h_velocity
	floor_h_velocity = 0.0
	
	#finds the floor
	var found_floor = false
	var floor_index = -1
	
	for x in range(s.get_contact_count()):
		var ci = s.get_contact_local_normal(x)
		if ci.dot(Vector2(0, -1)) > 0.6:
			found_floor = true
			floor_index = x
	
	#
	if shoot and not shooting:
		shoot_time = 0
		var bi = bullet.instance()
		var ss
		if siding_left:
			ss = -1.0
		else:
			ss = 1.0
		var pos = position + $bullet_shoot.position * Vector2(ss, 1.0)
		
		bi.position = pos
		get_parent().add_child(bi)
		
		bi.linear_velocity = Vector2(800.0 * ss, -80)
		
		$sprite/smoke.restart()
		$sound_shoot.play()
		
		add_collision_exception_with(bi)#makes the bullet and this not collide
		
	else:
		shoot_time += step
	
	if found_floor:
		airborne_time = 0.0
	else:
		airborne_time += step#times how long spent airborne
	
	var on_floor = airborne_time < MAX_AIRBORNE_TIME
	
	#the jump is processed here
	if jumping:
		if lv.y > 0:
			#sets of the jumping flag if going down
			jumping = false
		elif not jump:
			stopping_jump = true
		
		if stopping_jump:
			lv.y += STOP_JUMP_FORCE * step
	
	if on_floor:
		#processes logic when character is on floor
		if move_left and not move_right:
			if lv.x > -WALK_MAX_VELOCITY:
				lv.x -= WALK_ACCEL * step
		
		elif move_right and not move_left:
			if lv.x < WALK_MAX_VELOCITY:
				lv.x += WALK_ACCEL * step
		
		else:
			var xv = abs(lv.x)
			xv -= WALK_DEACCEL * step
			if xv < 0:
				xv = 0
			lv.x = sign(lv.x) * xv
		
		#check the jump
		if not jumping and jump:
			lv.y = -JUMP_VELOCITY
			jumping = true
			stopping_jump = false
			$sound_jump.play()
		
		#check siding
		if lv.x < 0 and move_left:
			new_siding_left = true
		elif lv.x > 0 and move_right:
			new_siding_left = false
		
		if jumping:
			new_anim = "Jumping"
		elif abs(lv.x) < 0.1:
			if shoot_time < MAX_SHOOT_POSE_TIME:
				new_anim = "Idle_Gun"
			else:
				new_anim = "Idle"
		else:
			if shoot_time < MAX_SHOOT_POSE_TIME:
				new_anim = "Run_Gun"
			else:
				new_anim = "Run"
		
	else:
		#process character information in the air
		if move_left and not move_right:
			if lv.x > -WALK_MAX_VELOCITY:
				lv.x -= AIR_ACCEL * step
		
		elif move_right and not move_left:
			if lv.x < WALK_MAX_VELOCITY:
				lv.x += AIR_ACCEL * step
		
		else:
			var xv = abs(lv.x)
			xv -= AIR_DEACCEL * step
			if xv < 0:
				xv = 0
			lv.x = sign(lv.x) * xv
		
		if lv.y < 0:
			if shoot_time < MAX_SHOOT_POSE_TIME:
				new_anim = "Jumping_Gun"
			
			else:
				new_anim = "Jumping"
			
		else:
			if shoot_time < MAX_SHOOT_POSE_TIME:
				new_anim = "Falling_Gun"
			else:
				new_anim = "Falling"
		
	#update siding
	if new_siding_left != siding_left:
		if new_siding_left:
			$sprite.scale.x = -1
		else:
			$sprite.scale.x = 1
		
		siding_left = new_siding_left
	
	#change animation
	if new_anim != anim:
		anim = new_anim
		$anim.play(anim)
	
	shooting = shoot
	
	#apply the floor velocity
	if found_floor:
		floor_h_velocity = s.get_contact_collider_velocity_at_position(floor_index).x
		lv.x += floor_h_velocity
	
	#apply gravity and set back the linear velocity
	lv += s.get_total_gravity() * step
	s.set_linear_velocity(lv)

If anyone has questions please let me know.

TwistedTwigleg

(I edited the first post so the code is formatted correctly :smile: )

Edit: Maybe try changing var on_floor = airborne_time < MAX_AIRBORNE_TIME to var on_floor = found_floor? I looked at the source code on Github (and ran the project on Github), and the code responsible for checking if the player is on the ground is the same...

Do you have the input actions set up? Initially when I ran the demo from Github I tried to use WASD, but the inputs are bound to the arrow keys. Maybe you are using the wrong/missing input actions?

d4v3y_5c0n3s

Sorry, that didn't fix it. The controls do work if I move the robot before it hits the ground, but once that happens it tips over with the same problems as before.

TwistedTwigleg

@d4v3y_5c0n3s said: Sorry, that didn't fix it. The controls do work if I move the robot before it hits the ground, but once that happens it tips over with the same problems as before.

Strange. At least we know it's not a input problem!

I copy-pasted the code into the player from the Github demo project, everything works (minus the animations that are not in the demo project). This makes me think the problem might be how your player scene is set up, since the code should (in theory) not work with the demo project if the code is the problem.

I would try checking your player scene and seeing if there's anything missing/different in comparison to the Github version. Another thing to do is add print statements around key parts of the code, especially movement related code. Here are a few places I'd suggest add print statements to:

if found_floor: airborne_time = 0.0 print ("floor found!") else: airborne_time += step#times how long spent airborne

if on_floor: print ("on the floor") #processes logic when character is on floor "..."

d4v3y_5c0n3s

(Sorry for the delay) I tested the print statements, and it never says that my character finds the floor. This means the problem is in the character itself. I will look into that next. Thanks for the help!